subroutine hec_dig_print
c
c prints the amplitude filtering coefficients
c        the time filtering coefficients
c        the t0's
c
      implicit none
c
      include'hec_par.inc'      ! shared parameters
      include'hec_datacard.inc' !user datacard values
      include'hec_dig_sys.inc'  ! digital filtering system common
      include'hec_geo.inc'      ! geometry correspondence tables
c
      integer ic, i_t, iw
      character*12 cg
      integer n_t
c
c print the filtering coefficients
c
      if (pr_dig .gt. 1) then
c
c build the format (2i4,[dig_nwpar]G14.7)
c insist that 0<dig_nwpar<10
c
        if (dig_nwpar .gt. 0 .and. dig_nwpar .lt. 10) then
          cg = '(2i4, G14.7)'
          write(cg(6:6),'(i1)') dig_nwpar
        else
          print *,' *** ERROR: hec_dig_print: '
          print *,'     the number of parameters is out of range',
     +      dig_nwpar
          stop
        endif
c 
        print *, ' '
        print *, ' *** filtering coefficients and t0''s for version', 
     +    dig_weight_version
        print *, '     number of time slices used in filtering ', 
     +    dig_nslice
        print *, '     number of coefficients ', dig_nwpar
        print *, '     reference time slice ', dig_slice_1
        print *, '     tdc offset for timing ', dig_t_global
        print *, '     reference cell for t0''s ', dig_ic_ref 
c
        print *, ' '
        print *, ' *** printing the amplitude filtering coefficients'
        print *, ' ic  i_t  coefficients'
        do ic = 1, i_adc_used
          do i_t = 1, dig_nslice
            write(6,cg) ic, i_t, (dig_amp_par(ic,i_t,iw),iw=1,dig_nwpar)
          enddo
        enddo
c 
        print *, ' '
        print *, ' *** printing the time filtering coefficients'
        print *, ' ic  i_t  coefficients'
        do ic = 1, i_adc_used
          do i_t = 1, dig_nslice
            write(6,cg) ic, i_t, (dig_tim_par(ic,i_t,iw),iw=1,dig_nwpar)
          enddo
        enddo
      endif
c
c find out how many non-zero raw t0's there are, then print them
c only if t0's are requested
c
      if (mk_dig .gt. 1) then
        print *, ' '
        n_t = 0
        do ic = 1, i_adc_used
          if (dig_t0_raw(ic) .gt. 0.) n_t = n_t + 1
        enddo
        if (n_t .gt. 0) then
          print *, 
     +      ' *** printing the non-zero raw t0''s and related t0''s'
          print *, ' ic    toff(ns)   t0(ns)'
          do ic = 1, i_adc_used
            if (dig_t0_raw(ic) .gt. 0.) then
              if (ic_connected(ic)) then
                write(6, '(i4,2f10.2)') 
     +            ic, dig_t0_raw(ic), dig_t0(ic)
              else
                write(6, '(i4,2f10.2,a)')  ic, dig_t0_raw(ic), 
     +            dig_t0(ic), ' but unconnected cell!!'
              endif
            endif
          enddo
        else
          print *, ' *** all raw t0''s and t0''s are set to zero'
        endif
      endif
c
      end