subroutine hec_dig_read_weights
c
c read parameters for amplitude weights
c read raw t0's
c from file dig_weight_amp.dat
c
c read parameters for amplitude for time weights
c from file dig_weight_tim.dat
c
c compute t0's
c
      implicit none
c
      include'hec_par.inc'      ! shared parameters
      include'hec_datacard.inc'
      include'hec_dig.inc'      ! digital filtering common
      include'hec_dig_sys.inc'  ! digital filtering system common
      include'hec_geo.inc'      ! geometry correspondence tables 
c
c local variables
c
      integer ic, i_t, iw
      integer dig_weight_version_tim
      character*8 cg
      integer n_raw, n, n_p
      real t0_raw, t0_raw_ref
      integer nbad, ic_bad(i_adc_dim), i, j
c
c open file for parameters for amplitude weights and raw t0's
c
      open(unit=10,file='dig_weights_amp.dat',status='OLD')
c
c see inc/hec_dig_sys.inc for a description of the variables
c
      read (10,*,ERR=11,END=10) dig_weight_version
      read (10,fmt='(I1)',ERR=11,END=10) dig_nslice
      read (10,fmt='(I1)',ERR=11,END=10) dig_nwpar
      read (10,fmt='(I1)',ERR=11,END=10) dig_slice_1
      if (irunpd .ge. 7) then
        read (10,*,ERR=11,END=10) dig_t_global
        read (10,*,ERR=11,END=10) dig_ic_ref
      endif
c
c echo version to output
c
      print *, ' '
      print *, ' *** reading amplitude filtering parameters and'
      print *, '     raw t0''s for version', dig_weight_version
c
c build the format (dig_nwpar)G14.7
c insist that 0<dig_nwpar<10
c
      if (dig_nwpar .gt. 0 .and. dig_nwpar .lt. 10) then
        cg = '( G14.7)'
        write(cg(2:2),'(i1)') dig_nwpar
      else
        print *,' *** ERROR: hec_dig_read_weights: '
        print *,'     the number of parameters is out of range', 
     +    dig_nwpar
        stop
      endif
c     
c read parameters for amplitude weights 
c
      do ic = 1, i_adc_used
        do i_t = 1, dig_nslice
          if (dig_weight_version .eq. 990810) then
            read(10,fmt='(5G15.7)',ERR=11,END=10)
     +        (dig_amp_par(ic,i_t,iw), iw=1, dig_nwpar)
          else
            read(10,fmt=cg,ERR=11,END=10)
     +        (dig_amp_par(ic,i_t,iw), iw=1, dig_nwpar)
          endif
        enddo
      enddo
c
c read raw t0's for each cell
c
      n_raw = 0
      do while (n_raw .le. i_adc_used)
        read(10,*,ERR=11,END=5) ic, t0_raw
        if (ic .ge. 1 .and. ic .le. i_adc_used) then
          dig_t0_raw(ic) = t0_raw
          n_raw = n_raw + 1
        else
          print *,' *** ERROR: hec_dig_read_weights: '
          print *,'     error reading raw t0''s , bad ic ', ic
          stop
        endif
      enddo
 5    continue
      close(10)      
c
c look for cells that have good amplitude weight parameters
c bad if one of the parameters is zero
c keep track locally of bad connected cells for printing only
c
      n = 0
      nbad = 0
      do ic = 1, i_adc_dim  
        ic_has_amp_weights(ic) = .true.
        do i_t = 1, dig_nslice
          do iw = 1, dig_nwpar
            if (dig_amp_par(ic,i_t,iw) .eq. 0.) then
              ic_has_amp_weights(ic) = .false.
            endif
          enddo
        enddo
        if (ic_has_amp_weights(ic)) then
          n = n + 1
        else
          if (ic_connected(ic)) then
            nbad = nbad + 1
            ic_bad(nbad) = ic
          endif
        endif
      enddo
      print *, '     good parameters read for ', n, ' channels'
      if (nbad .gt. 0) then
        print *, '     ***** WARNING *****'
        print *, '     bad parameters read for ', nbad, 
     +    ' connected channels:'
        do i = 1, nbad/10 + 1
          write(*, '(5x,10i5)') 
     +      (ic_bad(j), j=1+10*(i-1), min(10+10*(i-1), nbad))
        enddo
      endif
c
c set the t0 values (the actual t0's used by the dig package)
c only do it for cells that have a dig_t0_raw != 0
c
      t0_raw_ref = dig_t0_raw(dig_ic_ref)
      n = 0
      n_p = 0
      do ic = 1, i_adc_dim
        if (dig_t0_raw(ic) .ne. 0.) then
          dig_t0(ic) = dig_t0_raw(ic) - t0_raw_ref
          n_p = n_p + 1
          if (.not.ic_connected(ic)) print *, 
     +      '     *** non-zero raw t0''s read for unconnected channel '
     +      ,ic
        endif
        if (dig_t0(ic) .ne. 0.) n = n + 1
      enddo
      if (n_raw .gt. 0) then
        print *, '     raw t0''s read for ', n_raw, ' channels, ',
     +    'of which ', n_p, ' are non-zero' 
        print *, '     a total of ', n, ' non zero t0''s have been set'
        if (mk_dig .eq. 1) then
          print *, '     they WILL NOT be used in digital filtering'
        else
          print *, '     they will be used in digital filtering'
        endif
      else
        print *, '     no raw t0''s read'
        print *, '     all t0''s have been set to zero'
      endif
c
c open file for parameters for time weights
c
      open(unit=10,file='dig_weights_tim.dat',status='OLD')
c
c see inc/hec_dig_sys.inc for a description of the variables
c
      read (10,*,ERR=21,END=20) dig_weight_version_tim
c
      if (dig_weight_version_tim .ne. dig_weight_version) then
        print *,' *** ERROR: hec_dig_read_weights: '
        print *,'     time digital filtering weights version is ',
     +          dig_weight_version_tim
        print *,'     which is not the same as for amplitude weights'
        stop
      endif
      print *, ' '
      print *, ' *** reading time filtering parameters for version ',
     +  dig_weight_version
c
c read coefficients for time weights 
c
      do ic = 1, i_adc_used
        do i_t = 1, dig_nslice
          if (dig_weight_version .eq. 990810) then
            read(10,fmt='(5G15.7)',ERR=21,END=20)
     +        (dig_tim_par(ic,i_t,iw), iw=1, dig_nwpar)
          else
            read(10,fmt=cg,ERR=21,END=20)
     +        (dig_tim_par(ic,i_t,iw), iw=1, dig_nwpar)
          endif
        enddo
      enddo
      close(10)
c
c look for cells that have good time weight parameters
c bad if one of the parameters is zero
c
      n = 0
      nbad = 0
      do ic = 1, i_adc_dim  
        ic_has_tim_weights(ic) = .true.
        do i_t = 1, dig_nslice
          do iw = 1, dig_nwpar
            if (dig_tim_par(ic,i_t,iw) .eq. 0.) then
              ic_has_tim_weights(ic) = .false.
            endif
          enddo
        enddo
        if (ic_has_tim_weights(ic)) then
          n = n + 1
        else
          if (ic_connected(ic)) then
            nbad = nbad + 1
            ic_bad(nbad) = ic
          endif
        endif
      enddo
      print *, '     good parameters read for ', n, ' channels'
      if (nbad .gt. 0) then
        print *, '     bad parameters read for ', nbad, 
     +    ' connected channels:'
        do i = 1, nbad/10 + 1
          write(*, '(5x,10i5)') 
     +      (ic_bad(j), j=1+10*(i-1), min(10+10*(i-1), nbad))
        enddo
      endif
c
      return
c
c check for read errors
c
 10   continue
      print *,' *** ERROR: hec_dig_read_weights: '
      print *,'     error reading amplitude filtering parameters'
      print *,'     premature end of file'
      stop
 11   continue
      print *,' *** ERROR: hec_dig_read_weights: '
      print *,'     error reading amplitude filtering parameters'
      stop
 20   continue
      print *,' *** ERROR: hec_dig_read_weights: '
      print *,'     error reading time filtering parameters'
      print *,'     premature end of file'
      stop
 21   continue
      print *,' *** ERROR: hec_dig_read_weights: '
      print *,'     error reading time filtering parameters'
      stop
c
      end